home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Shareware Overload Trio 2
/
Shareware Overload Trio Volume 2 (Chestnut CD-ROM).ISO
/
dir26
/
epi601_2.zip
/
FILES07.EXE
/
CASECON6.PGM
< prev
next >
Wrap
Text File
|
1994-08-22
|
3KB
|
77 lines
*Program to set up cases and controls for PSP study
READ EPIDEMIC
DEFINE GROUP STRING WIDTH = 7
*Set up a defined variable, to be "Case", "Control", or "Other"
DEFINE NEURO number global width =4 0
DEFINE MOTOR #### global 0
*Variables for number of neuro and motor symptoms
*define sets both to zero before each record
IF LIPS = "Y" THEN NEURO = NEURO + 1
IF FACE = "Y" THEN NEURO = NEURO + 1
IF EARS = "Y" THEN NEURO = NEURO + 1
IF FINGERS = "Y" THEN NEURO = NEURO + 1
IF TOES = "Y" THEN NEURO = NEURO + 1
IF LEGS = "Y" THEN NEURO = NEURO + 1
IF ARMS = "Y" THEN NEURO = NEURO + 1
IF TALKING = "Y" THEN MOTOR = MOTOR + 1
IF WALKING = "Y" THEN MOTOR = MOTOR + 1
IF GETTINGUP= "Y" THEN MOTOR = MOTOR + 1
IF BREATHING= "Y" THEN MOTOR = MOTOR + 1
IF DIZZINESS= "Y" THEN MOTOR = MOTOR + 1
*NEURO and MOTOR now contain the symptom counts
LET GROUP = " "
*Set GROUP to blank. This is important!!
IF (ILL = "Y") AND (DATEONSET = "07/30") AND (HEADACHE = "Y") AND\
(NEURO >= 2) AND (MOTOR >= 2) THEN GROUP = "CASE"
*Use all the case criteria to label the cases
IF (GROUP <> "CASE") and (ILL = "N") THEN GROUP = "CONTROL"
*Label as controls only those not ill
SET IGNORE = ON
*Ignore missing values in making tables, so that they will be 2 x 2
SELECT GROUP = "CASE" OR GROUP = "CONTROL"
*Include only cases and controls
DEFINE ANYFISH STRING width = 1
DEFINE ANYSHRIMP <A>
DEFINE ANYCLAMS STRING width = 1
DEFINE ANYLOBSTER <A>
*variables can be defined in either of the above two ways
IF FISH = "Y" OR FISHSOUP = "Y" THEN ANYFISH = "+" ELSE ANYFISH = "-"
IF SHRIMP = "Y" OR SHRIMPSOUP = "Y" THEN ANYSHRIMP = "+" ELSE ANYSHRIMP = "-"
IF CLAMS = "Y" OR CLAMSOUP = "Y" THEN ANYCLAMS = "+" ELSE ANYCLAMS = "-"
IF LOBSTER = "Y" OR LOBSTRSOUP = "Y" THEN ANYLOBSTER = "+" \
ELSE ANYLOBSTER = "-"
*Set up variables for combinations of foods
DEFINE AGEGROUP STRING width = 9
RECODE AGE to AGEGROUP BY 10
*Set up age groups
HEADER 1 SAN FELIPE CASES AND CONTROLS WITH ONSET JULY 30
ECHO Cases and Controls identified. GROUP is the identifier.
ECHO The variables are:
VARIABLES
*Show a list of variables
ECHO Ready for more commands....
ECHO Try LIST to see the records.
?EPI6> ?
ECHO
ECHO Now type TABLES ANYCLAMS ILL to see an enormous odds ratio.
?EPI6> ?
ECHO You should, of course, make tables of other exposure variables
ECHO by illness status, for example, TABLES ANYLOBSTER ILL, to test
ECHO other hypotheses. Press <F3> to see the available variables.
ECHO
ECHO When you are through experimenting, press <F10> to return to the
ECHO menu.
ECHO
*Provide a message to the user and return to interactive mode
* for further commands....